[Author Prev][Author Next][Thread Prev][Thread Next][Author Index][Thread Index]
Re: ATM 18-point cell design
PFAFF2@delphi.com writes
>
>> TM26 has an article on it, complete with a BASIC program for calculating
>> 9- and 18-point cells. I'll not copy the entire program out (I'll
>> probably make lots of typos!).
>Amateur Telescope Making Book One has a write up on mechanical
>flotation systems. The 18 point is included. Using the simple math
>is probably quicker to do then keying in the BASIC program from TM, at least
>for me <G>. Does somebody have the program at a site that could be
>downloaded?
Out of sheer curiosity I keyed it in today, debugged (or, rather, de-
typo'd) it, made a few minor mods...
I'll stick it on my web site the next time I upload to it.
In the meantime, here it is:
<html><code>
10 CLS
20 PRINT "NINE AND EIGHTEEN POINT FLOTATION CELLS"
30 PI = 3.14159
40 PRINT : INPUT "9 OR 18 POINTS"; P
50 IF P = 9 THEN C7 = 1.5: C8 = 1.0472: C9 = .5236: GOTO 70
60 C7 = 3: C8 = .5236: C9 = .2618
70 INPUT "DIAMETER OF MIRROR"; R3
80 INPUT "DIAMETER OF CENTRAL HOLE (0 IF NONE)"; R1
90 INPUT "THICKNESS OF MIRROR AT EDGE"; H
100 INPUT "FOCAL RATIO"; FR
105 CLS
110 F = FR * R3
120 PRINT "------------------------------------------------------------------"
130 PRINT " "; P; "POINT FLOTATION CELL FOR MIRROR WITH"
140 PRINT " DIAMETER ="; R3; " CENTRAL HOLE ="; R1
150 PRINT "EDGE THICKNESS ="; H; " FOCAL LENGTH ="; F; " FOCAL RATIO ="; FR
160 PRINT "------------------------------------------------------------------"
170 PRINT
180 R3 = R3 / 2
190 R1 = R1 / 2
200 H = H - R3 * R3 / 4 / F
210 C = -2 * R1 ^ 4 - R3 ^ 4 - 16 * F * H * R1 * R1 - 8 * F * H * R3 * R3
220 B = 24 * F * H
230 R2 = SQR((-B + SQR(B * B - 12 * C)) / 6)
240 V = ((R2 ^ 4 - R1 ^ 4) / 16 / F - H * (R1 + R2) * (R1 - R2) / 2) * PI / C7
250 C1 = ((R2 ^ 5 - R1 ^ 5) / 20 / F + H / 3 * (R2 ^ 3 - R1 ^ 3)) / V * 2 * SIN(C8)
260 PRINT "RADIUS OF INNER SUPPORT POINTS = "; C1
270 C2 = ((R3 ^ 5 - R2 ^ 5) / 20 / F + H / 3 * (R3 ^ 3 - R2 ^ 3)) / V * 2 * SIN(C9)
280 PRINT "RADIUS OF OUTER SUPPORT POINTS ="; C2
285 PRINT
290 PRINT "TRIANGLES ARE ISOSCELES WITH:"
300 PRINT "BASE ="; C2 * 2 * SIN(C9)
310 A = C2 * COS(C9) - C1
320 PRINT "ALTITUDE ="; A
330 PRINT "BALANCE POINT ="; A * 2 / 3; "FROM THE VERTEX"
335 PRINT
340 IF P = 9 THEN 380
350 PRINT
360 PRINT "LENGTH OF BAR CONNECTING TRIANGLES ="; C1 + A * 2 / 3
370 PRINT "RADIUS OF CENTRE POINT OF BAR ="; (C1 + A * 2 / 3) * COS(C8)
380 END
</html></code>
--
Stephen Tonkin : UK Amateur Telescope Making Pages
<sft@aegis1.demon.co.uk> : <http://www.aegis1.demon.co.uk/atm.htm>